Board.KolibriOS.org

Code: Select all

;*******************************************************************************
; Static variables
;*******************************************************************************
LOADER_BASE	= 0x7C00
MAX_LOADER_SIZE = 512
MAX_CONFIG_SIZE = 0x1000

	org	LOADER_BASE
	use16
;*******************************************************************************
	jmp	short boot_code
	nop
;*******************************************************************************
; FAT12 section
;*******************************************************************************
virtual at $
  dbOEM 	db 'NYAOS1.0'		    ; OEM String
  dwSectSize	dw 512			    ; Bytes per sector
  dbClustSize	db 1			    ; Sectors per cluster
  dwResSect	dw 1			    ; # of reserved sectors
  dbFATCopies	db 2			    ; # of fat copies
  dwRootEntries dw 224			    ; # of root directory entries
  dwTotalSect	dw 2880 		    ; total # of sectors if < 32 meg
  dbMedia	db 0xF0 		    ; Media Descriptor
  dwSect%FAT	dw 9			    ; Sectors per FAT
  dwSect%Track	dw 18			    ; Sectors per track
  dwHeadNum	dw 2			    ; # of read-write heads
  ddHiddenSects dd 0			    ; # of hidden sectors
  ddHugeSect	dd 0			    ; if bsTotalSect is 0 this value is
					    ; the number of sectors
  dbBootDrive	db 0			    ; holds drive that the bs came from
  dbReserv	db 0			    ; not used for anything
  dbBootSign	db 29h			    ; boot signature 29h
  ddVolID	dd 0			    ; Disk volume ID also used for temp
					    ; sector # / # sectors to load
  dbVoLabel	db '           '	    ; Volume Label
  dbFSType	db 'FAT12   '		    ; File System type
  dwEnd 	dw 7DF1h
  svLen 	= $ - dbOEM
end virtual
file 'bootimg.img':dbOEM - LOADER_BASE,svLen
;*******************************************************************************
; Boot code begins
;*******************************************************************************
  boot_code:
	jmp	0x0:start
  start:
	cli				; Запрещаем маскируемые прерывания

;*******************************************************************************
	in	al, 0x70		; Запрещаем не маскируемые прерывания
	mov	bl, al
	or	al, 10000000b		; Ставим 8й бит
	out	70h , al		; RTC после записи байта в порт 0х70
	in	al, 0x71		; ожидают обращения к порту 0x71

;*******************************************************************************
	in	al, 0x92		; открываем адресную линию A20
	or	al, 2
	out	0x92, al

;*******************************************************************************
	mov	[dbBootDrive], dl	  ; save drive number
	xor	ax, ax			; Предпологется что 32-х битное
					; расширение и так равно нулю
	mov	es, ax			; Устанавливаем ss и ss в 0
	mov	ss, ax
	mov	sp, LOADER_BASE
	mov	di, LOADER_BASE + 512  ; Буффер для GDT сразу за образом

;*******************************************************************************
; Initializing unreal mode
;*******************************************************************************
	;shl     eax, 4
	;add     eax, edi
	;push    eax
	push	edi			; Сохраняем его
; Нудевой дескриптор
	;xor     eax, eax
	stosd
	stosd
; Плоский дескриптор
	or	ax, -1
	stosd
	mov	eax, 0x00CF9200 	; Флаги плоского дескриптора
	stosd

	push	8 * 2			; Длина GDT для загрузки в GDTR
	lgdt	[esp]
	add	sp, 6

	mov	eax, cr0		; Включаем PM (Protected mode)
	or	al, 1
	mov	cr0, eax

	mov	dx, 8			; Cмещение плоского элемента GDT
	mov	ds, dx			; Загружаем все сигментные регистры
	mov	es, dx
	;mov     ss, dx
	;mov     gs, dx
	;mov     fs, dx

	and	al, not 1
	mov	cr0, eax		; Отключаем PM

	sti				; Разрешаем маскируемые прерывания

	mov	al, bl			; Разрешаем не маскируемые прерывания
	out	0x70, al
	in	al, 0x71

	mov	dx, 92h
	in	al, dx
	or	al, 2
	out	dx, al

;*******************************************************************************
; Читаем boot.cfg
;*******************************************************************************
	mov	bx, LOADER_BASE + 512 + 512
        mov      cx, [dwRootEntries]    ; dwRootEntries
                                        ; *EntriesSize{32} /dwSectSize{512}
        shr      cx, 4                  ; << 5{*32} >> 9{/512} = >> 4{/16}

        xor     eax, eax
        mov     al, [dbFATCopies]
        mul     [dwSect%FAT]
        add     eax, [ddHiddenSects]
        add     ax, [dwResSect]         ; ax holds root directory location

        call    readsect

        mov     bx, LOADER_BASE + 512 + 512
        mov     al, [ds:bx]
        call    print_al

        ; ................................
        ; ................................
        ; ................................
        ; ................................

  exit:
        ;jmp     $
        xor     ah, ah
	int	16h			; Ожидаем нажатия любой клавиши

  error:
        jmp     exit

;*******************************************************************************
; Вспомогательные функции
;*******************************************************************************
  print_al: ; Использую временно, как отладчик
	push	eax
	xor	ah, ah
	ror	eax, 4
	call	print_hex_char
	shr	eax, 32 - 4
	call	print_hex_char
	mov	al, ' '
	int	10h
	pop	eax
	ret
  print_hex_char:
	cmp	al, 10
	sbb	al, 69h
	das
	mov	ah, 0x0E
	int	10h
	ret

;*******************************************************************************
; es:bx = Location, ax = Sector
;*******************************************************************************
  readsect:   ; es:bx = Location, ax = Sector
	push	ax cx
	;xor     dx, dx
	cwd				; for floppy
	div	[dwSect%Track]		; divide logical sect by track size
	inc	dl			; sector # begins at 1
	mov	[dbReserv], dl		; sector to read
	mov	cl, dl
	cwd				; logical track left in ax
	div	[dwHeadNum]		; leaves head in dl, cyl in ax
	mov	dh, [dbBootDrive]
	xchg	dl, dh			; head to dh, drive to dl
	mov	cx, ax			; cyl to cx
	xchg	cl, ch			; low 8 bits of cyl to ch, hi 2 bits
	shl	cl, 6			; shifted to bits 6 and 7
	or	cl, [dbReserv]		; or with sector number
	mov	ax, 0x0201		; Read{0x02} one{0x01} sector
	int	0x13			; read sector
	jc	error			; display error message
	pop	cx ax
	ret				; return to caller

;*******************************************************************************
; Lets end up boot sector
;*******************************************************************************
if $ > LOADER_BASE + MAX_LOADER_SIZE
  'Error: MAX_LOADER_SIZE excepted'
end if

;*******************************************************************************
		rb 512 - 2 - $ + $$	; Заполняем оставшееся
		db 0x55, 0xAA		; the signature itself

;*******************************************************************************
; This's the end of the boot sector
;*******************************************************************************

  ; Это образ дискеты с файлом boot.cfg и ещё несколькими.
  file 'bootimg.img':MAX_LOADER_SIZE,$168000 - MAX_LOADER_SIZE

virtual at LOADER_BASE + MAX_LOADER_SIZE
  boot.cfg	rb MAX_CONFIG_SIZE	; Буффер для чтения файла конфигурации
   .len 	rd 1
  ;bDrive        rd 1
end virtual