Board.KolibriOS.org

Code: Select all

;-----------------------------------------------------------------------------
align 4
IDE_irq_14_handler:
        DEBUGF  1, "K : IDE_irq_14_handler \n"
        cmp     [IDE_common_irq_param], irq14_num
        jne     .exit

        pushfd
        cli
        pushad
        mov     [IDE_common_irq_param], 0
        mov     dx, [IDEContrRegsBaseAddr]
; test whether it is our interrupt?
        add     edx, 2
        in      al, dx
        test    al, 100b
        jz      @f
; clear Bus Master IDE Status register
; clear Interrupt bit
        out     dx, al
; clear Bus Master IDE Command register
        sub     edx, 2
        xor     eax, eax
        out     dx, al
; read status register and remove the interrupt request
        mov     edx, [hdbase]
        add     edx, 0x7
        in      al, dx
        popad
        popfd
        mov     al, 1
        ret
;--------------------------------------
align 4
@@:
        popad
        popfd
;--------------------------------------
align 4
.exit:
        mov     al, 0
        ret
;-----------------------------------------------------------------------------
align 4
IDE_irq_15_handler:
        DEBUGF  1, "K : IDE_irq_15_handler \n"
        cmp     [IDE_common_irq_param], irq15_num
        jne     .exit

        pushfd
        cli
        pushad
        mov     [IDE_common_irq_param], 0
        mov     dx, [IDEContrRegsBaseAddr]
        add     dx, 8
; test whether it is our interrupt?
        add     edx, 2
        in      al, dx
        test    al, 100b
        jz      @f
; clear Bus Master IDE Status register
; clear Interrupt bit
        out     dx, al
; clear Bus Master IDE Command register
        sub     edx, 2
        mov     al, 0
        out     dx, al
; read status register and remove the interrupt request
        mov     edx, [hdbase]
        add     edx, 0x7
        in      al, dx
        popad
        popfd
        mov     al, 1
        ret
;--------------------------------------
align 4
@@:
        popad
        popfd
;--------------------------------------
align 4
.exit:
        mov     al, 0
        ret
;-----------------------------------------------------------------------------
align 4
IDE_common_irq_handler:
        pushfd
        cli
        pushad
        DEBUGF  1, "K : IDE_common_irq_handler \n"	
        xor     ebx, ebx
        mov     eax, IDE_common_irq_param
	DEBUGF  1, "K : [IDE_common_irq_param] %x \n", [eax]:2
        mov     [eax], bl
; test whether it is our interrupt?
        mov     dx, [IDEContrRegsBaseAddr]
        add     edx, 2
        in      al, dx
	DEBUGF  1, "K : channel 1 interrupt? %x \n", eax
        test    al, 100b ; check channel 1 interrupt
	jnz	@f
	
	add     dx, 8
        in      al, dx
	DEBUGF  1, "K : channel 2 interrupt? %x \n", eax
        test    al, 100b ; check channel 2 interrupt
	jnz	@f
        DEBUGF  1, "K : IDE - no, it's not our interrupt \n"
        popad
        popfd
        mov     al, 0 ; no, it's not our interrupt
        ret
;--------------------------------------
align 4
@@:
; clear Bus Master IDE Status register
; clear Interrupt bit
	DEBUGF  1, "K : IDE - clear Interrupt bit \n"
        out     dx, al
; clear Bus Master IDE Command register
        sub     edx, 2
        xor     eax, eax
	DEBUGF  1, "K : IDE -  clear Bus Master IDE Command register \n"
        out     dx, al
; read status register and remove the interrupt request
        mov     edx, [hdbase]
        add     edx, 0x7
        in      al, dx
	DEBUGF  1, "K : read status register and remove the interrupt request %x \n", eax
	
        DEBUGF  1, "K : IDE - yes, this is our interrupt \n"
        popad
        popfd
        mov     al, 1 ; yes, this is our interrupt
        ret
;-----------------------------------------------------------------------------

Code: Select all

; \begin{Mario79}
; find HDD IDE DMA PCI device
; check for PCI BIOS
        mov     ax, 0xB101
        int     0x1A
        jc      .nopci
        cmp     edx, 'PCI '
        jnz     .nopci
; find PCI class code
; class 1 = mass storage
; subclass 1 = IDE controller
; a) class 1, subclass 1, programming interface 0x80
; This is a Parallel IDE Controller which uses IRQs 14 and 15.
        mov     ax, 0xB103
        mov     ecx, 1*10000h + 1*100h + 0x80
        mov     [es:BOOT_IDE_PI_16], cx
        xor     si, si  ; device index = 0
        int     0x1A
        jnc     .found_1 ; Parallel IDE Controller
; b) class 1, subclass 1, programming interface 0x8f
        mov     ax, 0xB103
        mov     ecx, 1*10000h + 1*100h + 0x8f
        mov     [es:BOOT_IDE_PI_16], cx
        xor     si, si  ; device index = 0
        int     0x1A
        jnc     .found_1
; c) class 1, subclass 1, programming interface 0x85
        mov     ax, 0xB103
        mov     ecx, 1*10000h + 1*100h + 0x85
        mov     [es:BOOT_IDE_PI_16], cx
        xor     si, si  ; device index = 0
        int     0x1A
        jnc     .found_1
; d) class 1, subclass 1, programming interface 0x8A
; This is a Parallel IDE Controller which uses IRQs 14 and 15.
        mov     ax, 0xB103
        mov     ecx, 1*10000h + 1*100h + 0x8A
        mov     [es:BOOT_IDE_PI_16], cx
        xor     si, si  ; device index = 0
        int     0x1A
        jnc     .found_1 ; Parallel IDE Controller
; Controller not found!
        xor     ax, ax
        mov     [es:BOOT_IDE_PI_16], ax
        jmp     .nopci
;--------------------------------------
.found_1:
; get memory base BAR4
        mov     ax, 0xB10A
        mov     di, 0x20        ; memory base is config register at 0x20
        push    cx
        int     0x1A
        jc      .no_BAR4        ;.nopci
        and     cx, 0xFFFC      ; clear address decode type
        mov     [es:BOOT_IDE_BASE_ADDR], cx
.no_BAR4:
        pop     cx
;--------------------------------------
.found:
; get Interrupt Line
        mov     ax, 0xB10A
        mov     di, 0x3c        ; memory base is config register at 0x3c
        push    cx
        int     0x1A
        jc      .no_Interrupt        ;.nopci

        mov     [es:BOOT_IDE_INTERR_16], cx
.no_Interrupt:
        pop     cx
;--------------------------------------
; get memory base BAR0
        mov     ax, 0xB10A
        mov     di, 0x10        ; memory base is config register at 0x10
        push    cx
        int     0x1A
        jc      .no_BAR0        ;.nopci

        mov     [es:BOOT_IDE_BAR0_16], cx
.no_BAR0:
        pop     cx
;--------------------------------------
; get memory base BAR1
        mov     ax, 0xB10A
        mov     di, 0x14        ; memory base is config register at 0x14
        push    cx
        int     0x1A
        jc      .no_BAR1        ;.nopci

        mov     [es:BOOT_IDE_BAR1_16], cx
.no_BAR1:
        pop     cx
;--------------------------------------
; get memory base BAR2
        mov     ax, 0xB10A
        mov     di, 0x18        ; memory base is config register at 0x18
        push    cx
        int     0x1A
        jc      .no_BAR2        ;.nopci

        mov     [es:BOOT_IDE_BAR2_16], cx
.no_BAR2:
        pop     cx
;--------------------------------------
; get memory base BAR3
        mov     ax, 0xB10A
        mov     di, 0x1C        ; memory base is config register at 0x1c
        push    cx
        int     0x1A
        jc      .no_BAR3        ;.nopci

        mov     [es:BOOT_IDE_BAR3_16], cx
.no_BAR3:
        pop     cx
;--------------------------------------
.nopci:
; \end{Mario79}