Board.KolibriOS.org

Code: Select all

 ; carpet bombing
           mov eax, 70
           mov ebx, kill
           int 0x40
 ; still alive ?
 ; head shot...
           mov eax, 9
           mov ebx, 0x80003000
           or ecx, -1
           int 0x40
kill:
  dd 0
  dd 0
  dd 0
  dd 0x20000
  dd 0x80001001
  db '/RD/1/KERNEL.MNT',0

Code: Select all

#ifdef __cplusplus
extern "C" {
#endif

Code: Select all

@echo off
echo ####################################################
echo #           Melibc builder                         #
echo #  usage: build [clean]                            #
echo ####################################################
rem #### CONFIG SECTION ####
set PATH=%PATH%;C:\MinGW\bin
set LIBNAME=libck.a
set INCLUDE=include
set CC=gcc
set CFLAGS=-c -nostdinc -DGNUC -I"%cd%\%INCLUDE%"
set AR=ar
set ASM=FASM.exe
set dirs=stdio memory kolibrisys string stdlib
rem #### END OF CONFIG SECTION ####

set objs=
set target=%1
if not "%1"=="clean" set target=all

set INCLUDE="%cd%"
call :Target_%target%

if ERRORLEVEL 0 goto Exit_OK

echo Probably at runing has been created error
echo For help send a report...
pause
goto :eof

:Compile_C
   %CC% %CFLAGS% %1 -o "%~dpn1.o"
   if not %errorlevel%==0 goto Error_Failed
   set objs=%objs% "%~dpn1.o"
goto :eof

:Compile_Asm
   %ASM% %1 "%~dpn1.o"
   if not %errorlevel%==0 goto Error_Failed
   set objs=%objs% "%~dpn1.o"
goto :eof

:Target_clean
   echo cleaning ...
   for %%a in (%dirs%) do del /Q "%%a\*.o"
goto :Exit_OK

:Target_all
   echo building all ...
   for %%a in (%dirs%) do (
      for %%f in ("%%a\*.asm") do call :Compile_Asm "%%f"
      for %%f in ("%%a\*.c") do call :Compile_C "%%f"
   )
   %AR% -ru %LIBNAME% %objs%
   if not %errorlevel%==0 goto Error_Failed
goto Exit_OK

:Error_Failed
echo error: execution failed
pause
exit 1

:Exit_OK
echo ####################################################
echo # All operations has been done...                  #
echo # For cleaning run this script with param " clean" #
echo ####################################################
pause
exit 0