Code: Select all

Это твой вариант... (14 строк)

========= из файла display asm Procedure Get_linear ===========
push ax ;сохраним все используемые регистры
push bx
push dx
shl dl, 1 ;математика: умножаем DL на 2 (DL=DL*2)...
mov al, dh ;в AL - ряд, 
mov bl, 160 ;который нужно умножить на 160
mul bl ;умножаем: AL(ряд)*160; результат --- в AX
mov di,ax ;результат умножения в DI
xor dh,dh ;аннулируем DH
add di,dx ;теперь в DI линейный адрес в видеобуфере...
pop dx ;восстанавливаем регистры...
pop bx
pop ax
ret 


А вот мой вариант (12 строк):
================================
push ax
push dx
xor ax, ax
xchg dh, al ; Имеем в dx =dl, а в ax = dh
mov di, ax
shl ax, 6 ; dh*64
shl di, 4 ; dh*16
add di, ax
add di, dx
shl di, 1 ; *2
pop dx
pop ax
ret
==================

То что мой вариант короче на 2 строки - это мелочи. Не в этом соль. Он быстрее, так как я использую команду сдвига (shl), а не умножения (mul). И регистров использует меньше (только ax).

Тут еще вот какой момент:

Ты используешь 160, т.е. уже умножил ширину экрана на 2. Но ведь ты потом все равно умножаешь на 2 dl. И почему только сдвиги:
Линейный адрес = (COL*80+RAW)*2
Отсюда:
Линейный адрес = (COL*64+COL*16+RAW)*2
Или:
Линейный адрес = ((COL shl 6) + (COL shl 4) + RAW) shl 1

Good luck. Slava V.

Здравствуйте, Олег!

Ваш эксперт Slava V. совершил очень существенную ошибку в своем оптимизированном варианте - это использование инструкции Xchg. Эта инструкция на время своего выполнения захватывает системную шину памяти (префикс Lock), что может привести (и приводит) к существенным задержкам.

В связи с этим предлагаю свой вариант:

_________________

Count_dx proc

push ax
push dx
mov al, dh 
cbw ;ax=dh
xor dh, dh 
mov di,ax
shl ax,6
shl di,4
add di,ax
add di,dx
shl di,1
pop dx
pop ax

Count_dx endp

_____________

Пришлось написать небольшую программку на Паскале, с помощью которой можно сравнить скорости работы различных вариантов этого фрагмента. Вот ссылка http://akp.nm.ru/get_linear_test.zip (1,8Kb).

Вот такие результаты я получил на своем Celeron 433 (тестирование проводил под Win 98):

исходный вариант (т.е. тот, который был опубликован в рассылке - прим. О.К.) - 1,713 мс (*)
вариант Slava V. - 2,393 мс
мой вариант - 1,540 мс

* - вот вам и медленная инструкции mul :) Ядра 6-го семейства процессоров от Intel (кстати, и от AMD тоже) содержат существенно ускоренные инструкции умножения, деления в отличии от предыдущих семейств. Вот так :)

По поводу результатов выполнения на других процах конкретных результатов привести не могу, т.к. нет возможности.

Алексей.